ASY-Forum dédié à Asymptote

[Fabrice]

Bonjour à tous,
J'ai déjà posé cette question sur le forum officiel, mais je n'ai pas vraiment eu de réponses.
Il faut d'abord savoir que ce code provoque chez moi un rectangle noir qui vient probablement de ma carte graphique que je vais changer sous peu.
Ma question porte surtout sur le code :
est-ce la façon la plus élégante pour construire un tétraèdre ?
Merci.

Code: Tout sélectionner

import three;
 import graph3;
 import math;
 import animate;
 import bsp;
 settings.outformat="pdf";
 settings.prc=true;
 settings.render=4;
size(8cm);
currentprojection;
pen p=fontsize(8pt);
 real a=2;
 triple[] z={(0,0,0),(a,0,0),(0,a,0),(0,0,a)};
 path3[] tetra={z[0]--z[1]--z[2]--cycle,z[0]--z[1]--z[3]--cycle,z[0]--z[2]--z[3]--cycle,z[3]--z[1]--z[2]--cycle};
 for (int i=0; i<tetra.length; ++i){ draw(surface(tetra[i]),lightgrey+opacity(0.5),nolight);
draw(tetra[i]);}
 triple N=midpoint(z[1]--z[2]);
 path3 g5=z[0]--N;
draw(g5,dashed);
draw(shift(N-z[0])*g5);
real t=0.5;
triple M=(1-t)*z[0]+t*N;
 path3 plan=plane(normal(tetra[0]),z[2]-z[1],shift(z[1]-N)*M);
triple[] T1=intersectionpoints(plan,tetra[2]);
triple[] T2=intersectionpoints(plan,tetra[1]);
draw(surface(T1[0]--T1[1]--T2[1]--T2[0]--cycle),red+opacity(0.5),nolight);
draw(T1[0]--T1[1]--T2[1]--T2[0]--cycle); limits(z[0],1.2*(z[1]+z[2]+z[3]));
xaxis3(Label("$x$",1),Arrow3);
yaxis3(Label("$y$",1),Arrow3);
 zaxis3(Label("$z$",1),Arrow3);
label("A",z[1],NW,p); label("B",z[2],S,p);
 label("C",z[3],NE,p); label("N",N,S+W,p);
 label("K",T1[0],NE,p);
label("J",T1[1],NE,p);
 label("L",T2[0],NW,p);
 label("I",T2[1],NW,p);
 label("O",z[0],NW,p);
 shipout(bbox(1mm,blue+1bp));


PS : un petit clin d'oeil à OG qui doit avoir dans ses fichiers une petite animation que j'ai écrite !

[GM]

Remarques préalables :
pourquoi tant d'import (inutiles) dans le code proposé ???
... et il y a des choses contradictoires : bsp et prc.

Ma question porte surtout sur le code :
est-ce la façon la plus élégante pour construire un tétraèdre ?

On espère tous un geometry3d... mais en attendant, ce n'est pas forcément simple... et il y a plusieurs méthodes.

Pour un simple tétraèdre, et si l'intention n'est pas de faire tourner la figure, on peut signaler l'existence de geoespace, qui donne cela :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geoespace;
triple A,B,C,D;
size(150,0);
A=(0,0,0);
B=(0,3,0);
C=(-1.5,1.5,0);
D=(1,1,3);
pyramide(D,A--B--C--cycle); 
trace();
label("$A$",A,sud);
label("$B$",B,sud);
label("$C$",C,sud);
label("$D$",D,nord);

Il reste à voir si cela peut être adapté à ta figure.

NB : Olivier, Philippe... je précise que c'est la version originale de geoespace... car la version modifiée de Philippe (qui a été proposée sur mathematex récemment) foire avec cet exemple simple.

[GM]

On peut aussi signaler l'existence de polyhedron_js.asy sur le site de Philippe.

Avec le code suivant :

Code: Tout sélectionner

import polyhedron_js;
settings.tex="pdflatex";
settings.outformat="pdf";
size(150cm);
currentprojection=orthographic(2,1,1);

polyhedron[] parr={tetrahedron};
filldraw(parr,new pen[]{0.95white},op=0.7);

tu obtiendras quelque chose comme cela que tu pourras faire tourner cette fois :

2010-03-13_150813.png (4.81 Kio) Vu 260 fois

polyhedron.pdf

(35.48 Kio) Téléchargé 12 fois

(possibilité de faire tourner le tétrahèdre dans le pdf si visualisation avec une version récente d'AcrobatReader)

Il n'y a encore aucune solution satisfaisante à 100% :

• Avec le couple bsp/geoespace... tu pourras avoir des pointillés, mais tu ne pourras pas faire tourner via opengl.
• Si tu préfères faire tourner (choix de prc/opengl), tu pourras jouer sur les transparences pour les faces cachées, mais les arrêtes cachées ne seront pas en pointillés.

[pivaldi]

NB : Olivier, Philippe... je précise que c'est la version originale de geoespace... car la version modifiée de Philippe (qui a été proposée sur mathematex récemment) foire avec cet exemple simple.

Exact !
Essaye la nouvelle version.

[GM]

NB : Olivier, Philippe... je précise que c'est la version originale de geoespace... car la version modifiée de Philippe (qui a été proposée sur mathematex récemment) foire avec cet exemple simple.

Exact !
Essaye la nouvelle version.

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geoespace_pi;
triple A,B,C,D;
size(150,0);
A=(0,0,0);
B=(0,3,0);
C=(-1.5,1.5,0);
D=(1,1,3);
pyramide(D,A--B--C--cycle); 
trace();
label("$A$",A,sud);
label("$B$",B,sud);
label("$C$",C,sud);
label("$D$",D,nord);

Cela fonctionne ! C'est vrai que les pointillés sont bien mieux.

NB : Philippe, Olivier, je précise que sur le forum, il y a les deux possibilités dorénavant : geoespace et geoespace_pi (nouvelle version de Philippe donnée ci-dessus).

[GM]

Toujours sur le sujet du tétraèdre, j'ai dans l'idée que celui qui fera geometry3 utilisera des structures.

Deux exemples :

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geoespace_pi;
//defaultbackpen +=linewidth(0);
currentprojection=orthographic(10,4,6);
size(250);
 
real a=5;
 
struct PYRA { triple S;
              path3 base;
              triple[] sb;
              shape fa;
              pen colar;
              pen colfa;
              void operator init(triple S, path3 base, pen colar=black, pen colfa=white) {
                    this.S=S;
                    this.base=base;
                    this.colar=colar;
                    this.colfa=colfa;
                    for(int i=0; i<length(this.base); ++i) {
                     this.sb.push(point(this.base,i));
 
                    }
                    this.sb.cyclic=true;
                    this.fa[0]=this.base;
                    for(int i=0; i<length(this.base); ++i) {
                      this.fa.push(this.S--this.sb[i]--this.sb[i+1]--cycle);
                    }
              }
              void misenscene() {
                    insertscene(this.fa,this.colfa,this.colar);
              }
}              
 
PYRA t=PYRA((0,0,a),(0,0,0)--(a,0,0)--(0,a,0)--cycle,red,paleblue+opacity(.5));
t.misenscene();
 
dot("$S$",t.S);
dot("$A$",t.sb[0]);
dot("$B$",t.sb[1]);
dot("$C$",t.sb[2]);
trace();
 

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import geoespace_pi;
//defaultbackpen +=linewidth(0);
currentprojection=orthographic(10,4,6);
size(250);
 
real a=5;
 
struct PYRA { triple S;
              path3 base;
              triple[] sb;
              shape fa;
              pen colar;
              pen colfa;
              void operator init(triple S, path3 base, pen colar=black, pen colfa=white) {
                    this.S=S;
                    this.base=base;
                    this.colar=colar;
                    this.colfa=colfa;
                    for(int i=0; i<length(this.base); ++i) {
                     this.sb.push(point(this.base,i));
 
                    }
                    this.sb.cyclic=true;
                    this.fa[0]=this.base;
                    for(int i=0; i<length(this.base); ++i) {
                      this.fa.push(this.S--this.sb[i]--this.sb[i+1]--cycle);
                    }
              }
              void misenscene() {
                    insertscene(this.fa,this.colfa,this.colar);
              }
}              
 
PYRA t=PYRA((0,0,a),(0,0,0)--(a,0,0)--(a,a,0)--(0,a,0)--cycle,blue,orange+opacity(.5));
t.misenscene();
 
dot("$S$",t.S);
dot("$A$",t.sb[0]);
dot("$B$",t.sb[1]);
dot("$C$",t.sb[2]);
trace();
 

[pivaldi]

Oui mais pas comme ça, j'espère !
Définir un objet ne signifie pas le tracer !
Et cette routine "trace()", qu'est-ce qu'elle vient faire dans Asymptote ? Aucun paquet ne fonctionne ainsi…
Pour bien faire, il faut surcharger les routines de tracé comme le font les autres paquets et tester le settings.render pour savoir comment faire le rendu.
Si je devais me lancer dans ce projet, je partirais certainement de polyhedron_js.asy en surchargent le module bsp pour qu'il trace les arrêtes cachées… il n'y en aurait pas pour très longtemps, finalement… mais comme je ne vais pas m'y lancer je

[GM]

Oui mais pas comme ça, j'espère !

Définir un objet ne signifie pas le tracer !

Là, je n'ai pas compris... car je peux le définir sans le tracer.

Et cette routine "trace()", qu'est-ce qu'elle vient faire dans Asymptote ? Aucun paquet ne fonctionne ainsi…

Tu ne voulais pas que je fasse geometry3 en 30mn tout de même ? J'ai repris ce que fournissait geoespace pour l'affichage... car je voulais juste montrer le principe de structure.

Pour bien faire, il faut surcharger les routines de tracé comme le font les autres paquets et tester le settings.render pour savoir comment faire le rendu.
Si je devais me lancer dans ce projet, je partirais certainement de polyhedron_js.asy en surchargent le module bsp pour qu'il trace les arrêtes cachées… il n'y en aurait pas pour très longtemps, finalement… mais comme je ne vais pas m'y lancer je

Oui, sors car tu devrais avoir honte de nous dire que c'est si rapide à faire que cela pourrait déjà être fait.

[pivaldi]

Définir un objet ne signifie pas le tracer !

Là, je n'ai pas compris... car je peux le définir sans le tracer.

Heu… oui, mille excuses, je n'avais pas vus le t.misentruc();

[Fabrice]

Bonjour à tous,

pourquoi tant d'import (inutiles) dans le code proposé ???
... et il y a des choses contradictoires : bsp et prc.

ce code n'est pas fini, j'y compte faire une animation (d'où animate) en montrant l'évolution de l'aire du rectangle, mais ma carte graphique ne me permet pas de le faire pour l'instant.
bsp et prc, là je suis d'accord.
Merci.
@+