ASY-Forum dédié à Asymptote

[GM]

Suite à une demande sur Mathematex, voilà un code qui pourra peut-être être utile à certains : obtenir la courbe représentative de la fonction de Heaviside (également appelée fonction échelon) définie par :

Code: Tout sélectionner

real H(real t) {return t < 0 ? 0 : 1;}

Un appel particulier de la fonction graph permet de renvoyer un guide[], pour tracer des courbes par morceaux : un paramètre cond de type bool3 permet de définir les conditions pour relier ou pas les points.

Code: Tout sélectionner

guide[] graph(picture pic=currentpicture, real f(real), real a, real b,
int n=ngraph, real T(real)=identity, bool3 cond(real),
interpolate join=operator --);

*** Pour masquer/découvrir le code Asymptote qui a permis de créer la figure, il faut cliquer dessus. ;-) ***

CODE ASYMPTOTE de la figure ci-dessus : Tout sélectionner

import graph;
size(300);
 
real xmin=-3,xmax=3;
real ymin=-1,ymax=2;
 
// Test pour savoir s'il faut relier les points ou pas lors de l'utilisation de graph.
bool3 condition(real x)
{
  static int derniersigne=0;
  int signe = sgn(x);
  bool b = derniersigne == 0 || signe == derniersigne; 
  derniersigne = signe;
  return b ? true : default;
}
 
// Définition de la fonction
real H(real t) {return t < 0 ? 0 : 1;}
 
// Tracé de la courbe
guide[] CH=graph(H,xmin,xmax,condition,n=400);
draw(CH,1.5bp+blue);
 
real margeaxe=.4;
xaxis(Label("$x$",align=Align),xmin-margeaxe,xmax+margeaxe,Ticks(NoZero),Arrow);
yaxis(ymin-margeaxe,ymax+margeaxe,Ticks(NoZero),Arrow);
 
shipout(bbox(2mm,Fill(white)));